*******************************************************
* Taiwan Semiconductor
* TSM900N10CP
* N-Channel 100V
* Date: 2024-12-12
* Version: 1
*******************************************************
.SUBCKT TSM900N10CP D G S
M1 3 GX S S NMOS  W= 4098929u L= 0.25u
M2 S GX S D PMOS1 W= 598929u L= 0.22242u
R1 D 3 70.803e-03 TC=6.0E-3 18.5E-6
CGS GX S 30e-12
CGD GX D 11e-12
RG G GY 1m
RTCV 100 S 1.0e6 TC=-10.e-04 0.0e-06
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3        TOX = 5e-8
+ NSUB = 2.65e+17  ETA=1e-4         VTO=2.32	   VMAX=2.5e5
+ KAPPA = 30.e-01  NFS =7.025e+11   Kp=6.688e-6   
+ LD = 0           IS = 0       TPG = 1     ) 
*************************************************************** 
.MODEL PMOS1 PMOS ( LEVEL = 3 TOX = 5e-8 
+NSUB = 2.9e+16 IS = 0 TPG = -1) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 15.5703E-9 T_MEASURED = 25 BV = 100
+TBV1= 8.8836E-04  TBV2=-3.3029E-07
+RS =5.1444E-3  N =1.3037    IS = 184.82E-12    IKF=4.5150
+EG = 1.149 XTI = 2.7e+00 TRS1 = 3.800e-03  
+CJO = 82.333E-12  VJ =.3905 M =.58907) 
****************************************************************

.ENDS