*******************************************************
* Taiwan Semiconductor
* TSM60NC1R5CP
* N-Channel 600V
* Date: 2024-1-5
* Version: 2
*******************************************************
.SUBCKT TSM60NC1R5CP D G S

M1 3 GX S S NMOS W= 146379u L= 2u 
M2 S GX S D PMOS W= 146379u L= 3.6798u   
R1 D 4 0.2492 TC=11.5e-03,0.0e-04
J1 4 S 3 JD 651338u 
.MODEL JD NJF (VTO = -10.10  BETA = 0.81e-01 LAMBDA = 0.626e-02 
+BETATCE = -10.1e-01 VTOTC = -0.04
+IS = 1e-18 N = 10 )
CGS GX S 126.1e-12 
CGD GX D 7.004e-12 
RG G GY 2
RTCV 100 S 1e6 TC=-0.300e-03,0
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD

C11    11   12         1E-12
V11    11   0          0Vdc
G11    4    S          VALUE { V(13, 0)*I(V11) }
E11    12   0  4   S   1
E12    13   0          TABLE {V(12)}
+0 1287
+1 858
+2 705
+3 614
+4 554
+5 501
+6 464
+7 438
+8 409
+9 386
+10 360
+15 274
+20 238
+25 165
+30 119
+35 70
+40 53
+45 37
+50 17
+60 12
+70 9
+80 7
+90 5
+100 3

**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 10e-8 
+ KP = 41.11787e-06 NSUB = 10.458e+16 
+ NFS = 3.155e+11  
+ LD = 0 IS = 0 TPG = 1 )
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 10e-8 
+NSUB = 3.000e+15 IS = 0 TPG = -1    )
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 7.504E-7  T_measured = 25 BV = 700
+TBV1=1.1400E-03  TBV2=-1.3461E-06  IKF=1.9791
+RS = 13.723E-3 N = 1.3286 IS =78.953E-12
+XTI = 2.074e+00 TRS1 = 2.05e-03	EG=1.16
+CJO = 0 )  
****************************************************************

.ENDS