*******************************************************
* Taiwan Semiconductor
* TSM480P06CP
* P-Channel -60V
* Date: 2024-01-16
* Version: 1
*******************************************************
.SUBCKT TSM480P06CP D G S
m1 3 gx s s pmos W=15332450u L=0.25u
m2 s gx s d nmos W=4332450u L=0.127u
r1 d 3 35.88E-3 tc=6.0957E-03,9.0504E-06
rg g gy 12
rtcv 100 s 1e6  TC=-1.4e-3
etcv gy gx 100 200 1
itcv s 100 1u
vtcv 200 s 1
dbd d s dbd 
cds d s 5p
****************************************************************
.model PMOS pmos (
+ LEVEL = 3           TOX = 7E-8             KAPPA=1.5
+ KP = 0.51432e-6     NSUB = 6.0132E16       VMAX=4.5e5 VTO=-2.14
+ NFS = 0.656E12      LD = 0                 IS = 0   
+ TPG = -1              )               
***************************************************************
.model NMOS nmos (
+ LEVEL = 3            TOX = 7E-8          NSUB = 2.1e16                    
+ IS = 0               TPG = -1              )                    
****************************************************************
.model DBD d (
+ FC = 0.1               TT = 13.411E-9                 T_MEASURED = 25   
+ TBV1=3.9522E-04        TBV2=7.5751E-07
+ BV = 81.1              RS = 2.8052E-3                 N = 1.3051
+ IS = 1.00E-9           EG = 1.16                      XTI = 0.6                       
+ TRS1 = -0.004          CJO = 203.56E-12               VJ = .3905
+ M = .33839             IKF=1.5821)                
****************************************************************

.ENDS