*******************************************************
* Taiwan Semiconductor
* TSM4800N15CX6
* N-Channel 150V
* Date: 2024-01-09
* Version: 1
*******************************************************
.SUBCKT TSM4800N15CX6 D G S
M1 3 GX S S NMOS  W= 1377887u L= 0.5u
M2 S GX S D PMOS1 W= 677887u L= 0.40584u
R1 D 3 355.949E-3 TC=8.5806E-03 2.6659E-05
RG G GY 3.5
RTCV 100 S 1.0e6
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
CDS S D 8p
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 5e-8
+ NSUB = 64.052e+16   Theta=0.3    VTO=4.335
+ KAPPA = 50.1581e-01 NFS = 22.47e+11 ETA= 0   Kp=4.84307e-6   
+ LD = 0 IS = 0 TPG = 1 ) 
*************************************************************** 
.MODEL PMOS1 PMOS ( LEVEL = 3 TOX = 5e-8
+NSUB = 0.60e+16 IS = 0 TPG = -1) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 6.03E-8 T_MEASURED = 25 BV = 178
+TBV1= 1.0026E-03 TBV2=-2.6748E-06
+RS =14.406E-3 N =1.4246    IS = 1.0000E-9    IKF=6.4727
+EG = 1.16 XTI = 2.5e+00 TRS1 = 4.500e-03  
+CJO = 98.00E-12 VJ =.3905 M =.57344) 
****************************************************************

.ENDS