*******************************************************
* Taiwan Semiconductor
* TSM2NB60CP
* N-Channel 600V
* Date: 2023-11-13
* Version: 1
*******************************************************
.SUBCKT TSM2NB60CP D G S
M1 3 GX S S NMOS W= 316448u L= 2u 
M2 S GX S D PMOS W= 316448u L= 1.5008u   
R1 D 3 3.694 TC=9.0201E-03,2.5780E-05
CGS GX S 111.694e-12 
CGD GX D 0.03e-12 
CDS D  S 7.2e-12
RG G GY 1m
RTCV 100 S 1e6 TC=0.31e-03,0e-6
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 10e-8 
+ KP = 36.5678e-06 NSUB = 5.6053e+16
+ NFS = 3.231e+11	ETA=0 KAPPA=1.5e-1
+ LD = 0 IS = 0 TPG = 1 )
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 10e-8 
+NSUB = 0.75e+16 IS = 0 TPG = -1    )
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1  TT=7.6E-7 T_measured = 25 BV = 666
+TBV1=1.1503E-03 TBV2= -1.0503E-06 IKF=25.278  
+RS = 12.414E-3 N = 1.3521 IS =178.39E-12
+XTI = 2.004e+00 TRS1 = 3.21e-03	EG=1.16
+CJO = 401.08E-12  M=1.3048  VJ=0.6041)  
****************************************************************
.ENDS