*******************************************************
* Taiwan Semiconductor
* TSM250N02DCQ
* N-Channel 20V
* Date: 2024-8-21
* Version: 1
*******************************************************
.SUBCKT TSM250N02DCQ D G S

**+params:  EP= {EP}
M1 3 GX S S NMOS W= 577894u L= 0.25u 
M2 S GX S D PMOS W= 577894u L= 0.46u
R1 D 3 15.45m TC= 40e-4 18u
CGS GX S 470p
CGD GX D 65p
RG G GY 0.26
RTCV 100 S 0.8e6 TC=-2.5m 5u
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 2.0e-8
+ RS = 0 KP = 7.85e-5  NSUB = 15e+16  THETA= 0.5 VTO= 1.05
+ KAPPA = 3.6 NFS = 15.5e+11 Rds=15e+9 
+ LD = 0 IS = 0 TPG = 1  ) 
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 2.0e-8  
+NSUB = 1e+15 IS = 0 TPG = -1 ) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 12.0e-9 T_MEASURED = 25 BV = 26.18 IBV=250u TBV1=980e-6 TBV2=-0.05u
+RS = 2.5m N = 1.084e+00 IS = 8.6e-12
+EG = 1.149 XTI = 1.026e+00 TRS1 = 2.410e-03 
+CJO = 100p VJ = 1.2 M = 0.50 ) 
****************************************************************

.ENDS