*******************************************************
* Taiwan Semiconductor
* TSM240N03CX6
* N-Channel 30V
* Date: 2024-8-21
* Version: 1
*******************************************************
.SUBCKT TSM240N03CX6 D G S

**+params:  EP= {EP} 
M1 3 GX S S NMOS W= 1657894u L= 0.27u 
M2 S GX S D PMOS W= 1657894u L= 0.34u
R1 D 3 16.02m TC= 54e-4 14u
CGS GX S 320p
CGD GX D 45p
RG G GY 1.2
RTCV 100 S 1.0e6 TC=-2.6m 2u
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 5.0e-8
+ RS = 0 KP = 7.85e-5  NSUB = 11e+16  THETA= 0.5 VTO= 2.70
+ KAPPA = 2e-1 NFS = 8.5e+11 Rds=15e+9 
+ LD = 0 IS = 0 TPG = 1  ) 
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 5.0e-8  
+NSUB = 1e+15 IS = 0 TPG = -1 ) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 30.0e-9 T_MEASURED = 25 BV = 34.8 IBV=250u TBV1=980e-6 TBV2=-0.01u
+RS = 3.8m N = 1.084e+00 IS = 10.0e-12
+EG = 1.149 XTI = 1.026e+00 TRS1 = 2.410e-03 
+CJO = 150p VJ = 1.3 M = 0.50 ) 
****************************************************************

.ENDS