*******************************************************
* Taiwan Semiconductor
* TSM1NB60CP
* N-Channel 600V
* Date: 2023-11-02
* Version: 1
*******************************************************
.SUBCKT TSM1NB60CP D G S
M1 3 GX S S NMOS W= 246126u L= 2u 
M2 S GX S D PMOS W= 266126u L= 1.0773u   
R1 D 3 9.3624 TC=8.9458E-03,2.2478E-05
CGS GX S 0.694e-12 
CGD GX D 0.03e-12 
CDS D  S 4.2e-12
RG G GY 1m
RTCV 100 S 1e6 TC=-0.65e-03,0e-6
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 10e-8 
+ KP = 34.1678e-06 NSUB = 6.6343e+16
+ NFS = 5.725e+11	ETA=0 KAPPA=0
+ LD = 0 IS = 0 TPG = 1 )
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 10e-8 
+NSUB = 2.4000e+16 IS = 0 TPG = -1    )
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1  TT=7.6E-7 T_measured = 25 BV = 699
+TBV1=1.0684E-03 TBV2= -9.5742E-07 IKF=11.978 
+RS = 24.784E-3 N = 1.4013 IS =192.53E-12
+XTI = 2.084e+00 TRS1 = 3.21e-03	EG=1.16
+CJO = 201.05E-12   M=1.0947  VJ=1.0009)  
****************************************************************

.ENDS