*******************************************************
* Taiwan Semiconductor
* TQM84KCX
* P-Channel -60V
* Date: 2024-03-08
* Version: 1
*******************************************************
.SUBCKT TQM84KCX D G S

m1 3 gx s s pmos W=26124u L=0.50u
m2 s gx s d nmos W=26124u L=0.520122u
r1 d 4 0.8228e-0 tc=0.0095,15e-6
cgs gx s 21.252e-12
cgd gx d 3.06e-12
rg g gy 100
rtcv 100 s 1e6 tc=0.8e-4,2.8e-6
etcv gy gx 100 200 1
itcv s 100 1u
vtcv 200 s 1
dbd d s dbd 
CDS D S 1.4p
J1 4 S 3 JD 26124u 
C11    11   12         1E-12
V11    11   0          0Vdc
G11    S    GX         VALUE { V(13, 0)*I(V11) }
E11    12   0  S   GX  1
E12    13   0          TABLE {V(12)}
+ 0 0
+ 0.4 130
****************************************************************
.MODEL JD PJF (VTO = -3.3 BETA = 7.515e-0 LAMBDA = 0.626e-02 
+BETATCE = -3.7e-01 VTOTC = -0.005 IS = 1e-18 N = 10  )
****************************************************************
.model PMOS pmos (
+ LEVEL = 3           TOX = 3E-8           RS = 0                         
+ KP = 8.75e-6         NSUB = 17.0325E15    KAPPA=1e-2
+ NFS = 0.38E12       LD = 0               IS = 0                         
+ TPG = -1              )               
***************************************************************
.model NMOS nmos (
+ LEVEL = 3            TOX = 3E-8          NSUB = 4e16                    
+ IS = 0               TPG = -1              )                    
****************************************************************
.model DBD d (
+ FC = 0.1             TT = 14.277E-9                T_MEASURED = 25                     
+ BV = 68.4            RS = 0.16114                  N=1.2045 
+ TBV1= 5.4705E-04     TBV2= 2.3902E-07                 
+ IS = 1.000E-12       EG = 1.16                     XTI = 1.65                       
+ TRS1 = 0.0018        CJO = 6.2676E-12              VJ = .75851
+ M = .28917            IKF=.1127)                
****************************************************************


.ENDS