*******************************************************
* Taiwan Semiconductor
* TQM300NB06CV
* N-Channel 60V
* Date: 2023-12-08
* Version: 1
*******************************************************
.SUBCKT TQM300NB06CV D G S
M1 3 GX S S NMOS  W=6263895u L=0.40u
M2 S GX S D PMOS1 W=6263895u L=0.0699u 
R1 D 3 19.44E-3 TC= 8.0399E-03 2.5622E-05
CGS GX S 22.1E-12
CGD GX D 0.1e-12
RG G GY 0.5
RTCV 100 S 1.0e6 TC=-1.4m 0u
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3        TOX = 7E-8
+ KP = 9.5441E-6   NSUB = 3.04E17   VTO=3.552	
+ KAPPA = 2.7E-0   NFS = 0.1755E12  ETA= 1E-4   THETA=0.7        
+ LD = 0           IS = 0           TPG = 1  ) 
*************************************************************** 
.MODEL PMOS1 PMOS ( LEVEL = 3 TOX = 7E-8 
+NSUB =1.5E16 IS = 0 TPG = -1) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.5 TT = 14.43E-9  T_MEASURED = 25 BV = 72.55 
+TBV1=1.0989E-03  TBV2=-7.0769E-07
+RS = 2.1058E-3 N = .99721 IS = 1.000E-12   IKF=2.3050
+EG = 1.149 XTI = 2.75e+00 TRS1 = 4.210e-03  
+CJO = 238.39E-12   VJ =.3905 M =.35823 ) 
****************************************************************

.ENDS