*******************************************************
* Taiwan Semiconductor
* TQM2N7002KCU
* N-Channel 60V
* Date: 2024-03-01
* Version: 1
*******************************************************
.SUBCKT TQM2N7002KCU D G S

M1 3 GX S S NMOS  W=26124u L=0.50u
M2 S GX S D PMOS1 W=26124u L=0.59318u
R1 D 4 0.2339 TC= 11.078E-03 1.086E-05
CGS GX S 20.E-12
CGD GX D 3.7647e-12
RG G GY 40
RTCV 100 S 1.0e6
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
J1 4 S 3 JD 26124u 
C11    11   12         1E-12
V11    11   0          0Vdc
G11    S    GX         VALUE { V(13, 0)*I(V11) }
E11    12   0  S   GX  1
E12    13   0          TABLE {V(12)}
+ -0.4 120
+ -0.3  90
+ -0.2  60 
+ -0.1  30
+ 0 0
***************************************************************
.MODEL JD NJF (VTO = -3.20 BETA = 8.31e-0 LAMBDA = 3.826e-02 
+BETATCE = -6.50e-01 VTOTC = -0.008 IS = 1e-18 N = 10  )
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 7E-8
+ KP = 17.85E-6   NSUB = 4.6025E16  	VMAX=3e5
+ KAPPA = 2.725E-2 NFS = 1.525E12 ETA    = 1E-4           
+ LD = 0 IS = 0 TPG = 1 ) 
*************************************************************** 
.MODEL PMOS1 PMOS ( LEVEL = 3 TOX = 7E-8
+NSUB =1.4E16 IS = 0 TPG = -1) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.5 TT = 12.362E-9 T_MEASURED = 25 BV = 71.8
+TBV1=1.0115E-03   TBV2= -4.7895E-07
+RS =.11321 N = .92398    IS = 22.055E-15    IKF=5.1985E-3
+EG = 1.149 XTI = 1.57e+00 TRS1 = 1.950e-03  
+CJO = 6.6610E-12  VJ =.3905 M =.14373) 
****************************************************************


.ENDS