*******************************************************
* Taiwan Semiconductor
* TQM138KDCU6
* N-Channel 60V
* Date: 2024-03-05
* Version: 1
*******************************************************
.SUBCKT TQM138KDCU6 D G S

M1 3 GX S S NMOS  W=26124u L=0.50u
M2 S GX S D PMOS1 W=26124u L=0.85357u
R1 D 4 0.1873 TC= 12.538E-03 1.086E-05
CGS GX S 20.92E-12
CGD GX D 3.7647e-12
RG G GY 40
RTCV 100 S 1.0e6
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
J1 4 S 3 JD 26124u 
C11    11   12         1E-12
V11    11   0          0Vdc
G11    S    GX         VALUE { V(13, 0)*I(V11) }
E11    12   0  S   GX  1
E12    13   0          TABLE {V(12)}
+ -0.4 120
+ -0.3  90
+ -0.2  60 
+ -0.1  30
+ 0 0
****************************************************************
.MODEL JD NJF (VTO = -3.20 BETA = 8.31e-0 LAMBDA = 3.826e-02 
+BETATCE = -6.90e-01 VTOTC = -0.008 IS = 1e-18 N = 10  )
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 7E-8
+ KP = 15.45E-6   NSUB = 2.2025E16  	VMAX=15e5
+ KAPPA = 2.725E-2 NFS = 0.873E12 ETA    = 1E-4           
+ LD = 0 IS = 0 TPG = 1 ) 
*************************************************************** 
.MODEL PMOS1 PMOS ( LEVEL = 3 TOX = 7E-8
+NSUB =0.5E16 IS = 0 TPG = -1) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.5 TT = 13.362E-9 T_MEASURED = 25 BV = 68.8
+TBV1=1.0079E-03   TBV2= -8.2325E-07
+RS =68.951E-3 N = 1.5591    IS = 1.0000E-9    IKF=98.590E-3
+EG = 1.149 XTI = 1.37       TRS1 = 3.00e-04  
+CJO = 6.4059E-12  VJ =1.2408 M =.19391) 
****************************************************************


.ENDS