*******************************************************
* Taiwan Semiconductor
* TQM123KCX
* N-Channel 100V
* Date: 2024-09-24
* Version: 2
*******************************************************

.SUBCKT TQM123KCX  D G S1
M1 3 GX S S NMOS  W=130620u L=0.50u
M2 S GX S D PMOS1 W=130620u L=0.24653u
R1 D 4 3.05 TC= 6.938E-03 1.386E-05
CGS GX S 5.421E-12
CGD GX D 2.3147e-12
RG G GY 37
RTCV 100 S 1.0e6
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S1 D DBD  
CDS S D 0.6p
Vs1 s s1 0
Fx2 0 x2 Vs1 1
Rx2 x2 0 1
Ix1 0 x1 1e-4
Rx1 x1 0 4.0e5 TC=1.2e-2 5e-5 

ER    4   3  VALUE { if( V(x2)>0.12,V(x1)/40*1.5*I(Vs1)**2+V(x1)*I(Vs1)**6,if( V(x2)>0, V(x2)*0.15,0) ) }


C11    11   12         1E-12
V11    11   0          0Vdc
G11    S    GX         VALUE { V(13, 0)*I(V11) }
E11    12   0  S   GX  1
E12    13   0          TABLE {V(12)}
+ -0.4 130
+ -0.3  95
+ -0.2  60 
+ -0.1  30
+ 0 0
C21    21   22         1E-12
V21    21   0          0Vdc
G21    D    GX         VALUE { V(23, 0)*I(V21) }
E21    22   0  D   GX  1
E22    23   0          TABLE {V(22)}
+ -4  16
+ 0 0
***************************************************************
.MODEL JD NJF (VTO = -3.20 BETA = 8.31e-0 LAMBDA = 3.826e-02 
+BETATCE = -6.50e-01 VTOTC = -0.008 IS = 1e-18 N = 10  )
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 7E-8
+ KP = 1.87E-6   NSUB = 5.6525E16  	VMAX=3.4e5
+ KAPPA = 2.725E-2 NFS = 1.063E12 ETA    = 1E-4           
+ LD = 0 IS = 0 TPG = 1 ) 
*************************************************************** 
.MODEL PMOS1 PMOS ( LEVEL = 3 TOX = 7E-8
+NSUB =0.19E16 IS = 0 TPG = -1) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.5 TT = 25.88E-9 T_MEASURED = 25 BV = 117.98
+TBV1=7.8418E-04   TBV2= 1.7386E-07
+RS = .1204 N = 1.2101    IS = 1.0000E-12    IKF=.15031
+EG = 1.149 XTI = 2.57e+00 TRS1 = 2.750e-03  
+CJO = 6.7537E-12  VJ =.70099 M =.18449) 
****************************************************************
.ENDS