*******************************************************
* Taiwan Semiconductor
* TQM050NB06CR
* 60V,104A N-Channel Power MOSFET
* Date: 2020-06-04
*******************************************************
.SUBCKT TQM050NB06CR D G S 
**+params:  EP= {EP}
M1 3 GX S S NMOS W= 10664315u L= 0.5u 
M2 S GX S D PMOS W= 10664315u L= 0.6u 
R1 D 3 3.4m TC=8.7m 20u 
CGS GX S 3.6n
CGD GX D 1p
RG G GY 1.5
RTCV 100 S 1.28e6 TC=-3.5m 100p
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 7.5e-8 
+ RS = 0 KP = 35e-6  NSUB = 5e+16  THETA= 0.5 VTO= 4.35
+ KAPPA = 5 NFS = 0.9e+12 Rds=55e+8
+ LD = 0 IS = 0 TPG = 1  ) 
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 7.5e-8  
+NSUB = 8e+15 IS = 0 TPG = -1 ) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 35e-9 T_MEASURED = 25 BV = 72.87 IBV=250u TBV1=1.1m TBV2=-0.1u
+RS = 1.33m N = 1.1 IS = 160e-12
+EG = 1.199 XTI = 1.026e+00 TRS1 = 4.2m
+CJO = 100p VJ = 12.5 M = 0.442 ) 
****************************************************************
.ENDS