*******************************************************
* Taiwan Semiconductor
* TQM033NB04CR
* 40V,121A N-Channel Power MOSFET
* Date: 2020-06-04
*******************************************************
.SUBCKT TQM033NB04CR D G S 
**+params:  EP= {EP}
M1 3 GX S S NMOS W= 17510000u L= 0.3u 
M2 S GX S D PMOS W= 17510000u L= 0.29u 
R1 D 3 1.8m TC=6.2m 11u 
CGS GX S 2.5n
CGD GX D 1p
RG G GY 1.5
RTCV 100 S 1e6 TC=-3m 9u
ETCV GX GY 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD S D DBD  
**************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 7.5e-8 
+ RS = 0 KP = 40e-6  NSUB = 1.17e+16  THETA= 0.5 VTO= 4.45
+ KAPPA = 1.5 NFS = 1.4085e+12 Rds=40e+8
+ LD = 0 IS = 0 TPG = 1  ) 
*************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 7.5e-8  
+NSUB = 8e+15 IS = 0 TPG = -1 ) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 27.4e-9 T_MEASURED = 25 BV = 47.88 IBV=250u TBV1=1.050m TBV2=-1u
+RS = 0.9m N = 1.1 IS = 50e-12
+EG = 1.199 XTI = 1.026e+00 TRS1 = 4.2m
+CJO = 200p VJ = 90.5 M = 0.142 ) 
****************************************************************
.ENDS