*******************************************************
* Taiwan Semiconductor_
* LTD7S24CAH
* 7700W, 24V Transient Voltage Suppressor
* Date: 2024-10-29
*******************************************************
*The model describes the characteristics of typical devices and is subject to change without notice. 		*
*SPICE model can be used for evaluating device performance, but it cannot reflect the real device 		*
*performance under any kind of conditions, nor to replace bread boarding for final verification. 		*
*TSC does not assume any warranty or liability whatever arising from their use. TSC does not assume 		*
*any warranty or liability for the values and functions of the SPICE model. The simulation results of 		*
*the SPICE model are to the best of our knowledge correct. However, users are fully responsible to verify	*
* and validate these results under the operating conditions and its application. TSC will not bear the 		*
*responsibility arising out of or in connection with any malfunction of the simulation model. In any kind 	*
*of cases, the current datasheet information is the design guideline and the only actual performance 		*
*specification. SPICE model provided by TSC is not warranted by TSC as completely and comprehensively 		*
*representing all the specifications and operating characteristics of the semiconductor product.		*
*
****************************************************************************************************************



.SUBCKT LTD7S24CAH 1 2
DF 6 60 DCJ
RRD 6 60 RRModel 23.8E6
RRU 1 6 RRModel 23.8E6
CS 1 60 1.2p

RLD 60 499 0.0075
VRD 499 n4 0
ELD n4 n3 nb ng 1
DLD n3 6 DLModel 

DR 6 1 DCJ
RLU 1 944 0.0075
VBDR 944 f4 0
ELU f4 f3 nb ng 1
DLU f3 6 DLModel

GB1 0 nb VALUE { table(V(x2,0),
+0,      1.00e-3,  
+1.e-3,  1.e-3,
+5e-3,   9.5578e-4,
+1e-1,    9e-4,
+1,        8.75e-4,
+10,       8.5e-4,
+80,      7.06e-4
+) }
RB1 nb 0 RBModel 29400
CB1 nb 0 0.1p

RG1 ng  ng3 0.005
DG1 ng3 ng2 DLModel
DG2 ng2 0   DCJ
IG1 0 ng 1e-6
L1 60 2 1.2E-09

Fx1 0 x2 VBDR 1
Fx2 0 x2 VRD 1
Rx1 x2 0 1

.MODEL DCJ D CJO=9.6E-9 M=.44514 VJ=1.0545
.MODEL RRModel RES TC1 = 0 TC2 = 0 T_MEASURED = 25
.MODEL DLModel D 
.MODEL RBModel RES TC1 = 0.67442m TC2 = -0.91388u T_MEASURED = 25

.ENDS