*******************************************************
* Taiwan Semiconductor
* BSS84W
* P-Channel -60V
* Date: 2023-10-26
* Version: 1
*******************************************************
.SUBCKT BSS84W D G S
m1 3 gx s s pmos W=26124u L=0.50u
m2 s gx s d nmos W=26124u L=1.45u
r1 d 4 2.100e-0 tc=0.0113,21e-6
cgs gx s 136.52e-12
cgd gx d 4.35e-12
rg g gy 2.4
rtcv 100 s 1e6 tc=-2.7e-4,0.55e-6
etcv gy gx 100 200 1
itcv s 100 1u
vtcv 200 s 1
dbd d s dbd 
J1 4 S 3 JD 26124u 
.MODEL JD PJF (VTO = -3.3 BETA = 4.615e-0 LAMBDA = 3.626e-02 
+BETATCE = -0.0e-01 VTOTC = -0.005 IS = 1e-18 N = 10  )
****************************************************************
.model PMOS pmos (
+ LEVEL = 3           TOX = 7E-8           RS = 0                         
+ KP = 15.0e-6        NSUB = 4.3325E15                        
+ NFS = 0.1E12       LD = 0               IS = 0                         
+ TPG = -1              )               
***************************************************************
.model NMOS nmos (
+ LEVEL = 3            TOX = 7E-8          NSUB = 2e16                    
+ IS = 0               TPG = -1              )                    
****************************************************************
.model DBD d (
+ FC = 0.1             TT = 1.8e-7                  T_MEASURED = 25   
+ TBV1=1.2850E-03      TBV2=-4.0397E-06                   
+ BV = 69              RS = 80.217E-3                 N = 1.3                 
+ IS = 24.995E-12      EG = 1.14                      XTI = 2.4                       
+ TRS1 = 0.0000        CJO = 7e-12                    VJ = 1
+ M = 0.001        IKF=32.651E-3)                
****************************************************************
.ENDS